A `use-package` enabled configuration of Paredit with an annoying problem worked around

paredit-setup.el

;;;;;;;;;;;;;
;; Paredit ;;
;;;;;;;;;;;;;

(use-package paredit
  :ensure t
  :init
  :config
  (show-paren-mode t)
  ;; Workaround for superfluous spaces inserted in e.g. pathnames, as
  ;; described here:
  ;; https://www.n16f.net/blog/fixing-unquote-splicing-behaviour-with-paredit/
  (defvar wsg-paredit-no-space-prefixes '(",@" "#p" "#P" "#c" "#C" "#2a" "#2A" "#+" "#-"))

  (defun wsg-paredit-space-for-delimiter (endp delimiter)
    (let ((point (point)))
      (or endp
          (seq-every-p
           (lambda (prefix)
             (and (> point (length prefix))
                  (let ((start (- point (length prefix)))
			(end point))
                    (not (string= (buffer-substring start end) prefix)))))
           wsg-paredit-no-space-prefixes))))

  (defun wsg-init-paredit-space-for-delimiter ()
    (add-to-list 'paredit-space-for-delimiter-predicates
		 'wsg-paredit-space-for-delimiter))

  (defun wsg-override-paredit-wrap-curly (&optional arg)
    (interactive "^p")
    (if (or (paredit-in-comment-p)
	    (paredit-in-string-p))
	(backward-paragraph)
      (paredit-wrap-curly)))

  (cl-defun wsg-paredit-next-sibling (arg)
    "Try to move to the next sexp at the same level as the one in which point
is."
    (interactive "p")
    (paredit-backward-up)
    (paredit-forward arg)
    (paredit-forward-down))

  (cl-defun wsg-paredit-previous-sibling (arg)
    "Try to move to the previous sexp at the same level as the one in which
point is."
    (interactive "p")
    (paredit-backward-up)
    (paredit-backward arg)
    (paredit-forward-down))

  :hook ((paredit-mode . wsg-init-paredit-space-for-delimiter)
	 (clojure-mode . enable-paredit-mode)
	 (cider-repl-mode . enable-paredit-mode)
	 (emacs-lisp-mode . enable-paredit-mode)
	 (eval-expression-minibuffer-setup . enable-paredit-mode)
	 (ielm-mode . enable-paredit-mode)
	 (lisp-mode . enable-paredit-mode)
	 (lisp-interaction-mode . enable-paredit-mode)
	 (scheme-mode . enable-paredit-mode)
	 (slime-repl-mode . enable-paredit-mode))
  :bind (:map paredit-mode-map
	      ("RET" . nil)
	      ("C-j" . paredit-newline)
	      ("M-[" . paredit-wrap-square)
              ("M-{" . wsg-override-paredit-wrap-curly)
              ("C-M-S-n" . wsg-paredit-next-sibling)
              ("C-M-S-p" . wsg-paredit-previous-sibling)))

Updated to handle complex numbers and arrays.

Update to enable backward paragraph jumping within certain contexts in paredit-enabled buffers.

Updated with two functions to jump to neighboring siblings.