PKGBUILD for https://github.com/xentec/tinc

PKGBUILD

# Maintainer: Xentec <xentec at aix0 dot eu>
# Contributor: Oliver (thechauffeur) Weidner <Oliver.Weidner@gmail.com>

pkgname=tinc-nolegacy-git
pkgver=1.1pre11.r311.gea75c24
pkgrel=1
pkgdesc="A full mesh p2p VPN daemon without legacy bloat"
arch=('i686' 'x86_64')
url="https://github.com/xentec/tinc"
license=('GPL')

depends=('lz4' 'miniupnpc')
makedepends=('cmake' 'git')
optdepends=('wxpython: gui support')

provides=('tinc')
conflicts=('tinc' 'tinc-pre' 'tinc-git' 'tinc-custom-git')

source=("$pkgname"::'git+https://github.com/xentec/tinc#branch=bare')
sha256sums=('SKIP')

pkgver() {
	cd "$srcdir/$pkgname"

	git describe --long | sed -r 's/^release.//;s/([^-]*-g)/r\1/;s/-/./g'
}

prepare() {
	cd "$srcdir/$pkgname"
	mkdir -p build && cd build

	cmake \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DCMAKE_BUILD_TYPE=Release \
		-Wno-dev \
		..
}

build() {
	cd "$srcdir/$pkgname/build"

	make
}

package() {
	cd "$srcdir/$pkgname/build"

	make DESTDIR="$pkgdir/" install
}