tinc-custom-git

PKGBUILD

# Maintainer: Xentec <xentec at aix0 dot eu>
# Contributor: Oliver (thechauffeur) Weidner <Oliver.Weidner@gmail.com>

pkgname=tinc-custom-git
pkgver=1.1pre11.r211.gbf50b35
pkgrel=1
pkgdesc="VPN (Virtual Private Network) daemon "
arch=('i686' 'x86_64')
url="https://github.com/gsliepen/tinc"
license=('GPL')

depends=('lzo2' 'zlib' 'openssl')
makedepends=('git')
optdepends=('wxpython: gui support')
#options=(!strip debug)

provides=('tinc')
conflicts=('tinc' 'tinc-pre' 'tinc-git')

source=("$pkgname"::'git+https://github.com/gsliepen/tinc#branch=1.1')
sha256sums=('SKIP')

pkgver() {
  cd "$pkgname"

  git describe --long | sed -r 's/^release.//;s/([^-]*-g)/r\1/;s/-/./g'
}

prepare() {
  cd "$pkgname"

  autoreconf -fsi
  ./configure \
	--prefix=/usr \
	--sysconfdir=/etc --localstatedir=/var --sbindir=/usr/bin \
  --with-systemd=/usr/lib/systemd/system \
	--disable-legacy-protocol # --enable-jumbograms
}

build() {
  cd "$pkgname"

  make
}

package() {
  cd "$pkgname"

  make DESTDIR="$pkgdir/" install

  install -dm755 "$pkgdir"/usr/share/tinc/examples
  cp -rv doc/sample-config "$pkgdir"/usr/share/tinc/examples
  find "$pkgdir"/usr/share/tinc/examples -type f -exec chmod 644 {} +
  find "$pkgdir"/usr/share/tinc/examples -type d -exec chmod 755 {} +
}