The clojure version with library core.async of debounce function

debounce.clj

(defn debounce-chan
  "Taken from https://github.com/swannodette/async-tests
   A little different with original one, write to channel after the interval
   instead of doing it in the beginning"
  ([source msecs]
   (debounce-chan (chan) source msecs))
  ([c source msecs]
   (go-loop [state ::init
             last-one nil
             cs [source]]
           (let [[_ threshold] cs
                 [v sc] (alts! cs)]
             (condp = sc
               source (condp = state
                        ::init (recur ::debouncing
                                      v
                                      (conj cs (timeout msecs)))
                        ::debouncing (recur state
                                            v
                                            (conj (pop cs) (timeout msecs))))
               threshold (if last-one
                           (do (>! c last-one)
                               (recur ::init
                                      nil
                                      (pop cs)))
                           (recur ::init last-one (pop cs))))))
   c))