using send_file for full non-blocking async fork w/ condvars

async_response.pl

# this function lets you run code in a fork
# and use a condvar on it to get the data
# and return it to the client in JSON form, all non-blocking and async
# based heavily on a trick by Assaf Gordon

sub async_response (&) {
    my $cb = shift;

    send_file(
        \'noop',
        streaming => 1,
        callbacks => {
            override => sub {
                my ( $respond, $response ) = @_;
                my $return = {};
                my $cv     = AnyEvent->condvar;

                $cv->begin( sub {
                    $respond->( Plack::Response->new(
                        200,
                        [ 'Content-type' => 'text/json' ],
                        to_json $return
                    )->finalize );
                } );

                $cv->begin;

                fork_call { $cb->() } sub {
                    $return = shift;
                    $cv->end;
                };

                $cv->end;
            },
        },
    );
}	

get '/do/something' => sub {
    async_response {
        # some blocking code
        # for example: VM::EC2

        my $ec2 = VM::EC2->new( ... );
        return {
            instance_names => [ map { $_->tags->{'Name'} } $ec2->instances ],
        };
    };
};