Basic demo for Wemos Lolin D32 PRO (ESP32) with build-in SD card reader, TFT display shield and SHT30 sensor

lolin_d32_pro.ino

/*************************************************************
Wemos Lolin D32 PRO (ESP32)
Basic demo
by Petr Lukas
*************************************************************/
#include <Adafruit_GFX.h>    // Core graphics library
#include <Adafruit_ST7735.h> // Hardware-specific library
#include <WEMOS_SHT3X.h> // SHT30 library
#include <SPI.h>
#include <SD.h> // SD card library

// TFT pins
#define TFT_CS     14
#define TFT_RST    33  
#define TFT_DC     27

// SD card pin
#define SD_CS    4

Adafruit_ST7735 tft = Adafruit_ST7735(TFT_CS,  TFT_DC, TFT_RST);
SHT3X sht30(0x45);

void setup(void) {
  Serial.begin(9600);
  pinMode(TFT_CS, OUTPUT);
  digitalWrite(TFT_CS, HIGH);
  pinMode(SD_CS, OUTPUT);
  digitalWrite(SD_CS, HIGH);
  
  tft.initR(INITR_144GREENTAB);
  tft.setTextWrap(false); // Allow text to run off right edge
  tft.fillScreen(ST7735_BLACK);
  
  tft.println("Starting board...");
  tft.println("Initializing SD card...");
  if (!SD.begin(SD_CS)) {
    tft.println("Failed!");
    return;
  }
  tft.println("OK");
  delay(2000);

  tft.println("Scanning SD card...");
  File root = SD.open("/");
  printDirectory(root, 0);
  root.close();
  delay(2000);
  tft.println("Loading images...");
  delay(1000);
  
  tft.fillScreen(ST77XX_BLACK); 
  bmpDraw("/picture1.bmp", 0, 0);
  delay(3000);
  
  tft.fillScreen(ST77XX_BLACK); 
  bmpDraw("/picture2.bmp", 0, 0);
  delay(3000);
  
  tft.fillScreen(ST77XX_BLACK); 
  bmpDraw("/picture3.bmp", 0, 0);
  delay(3000);

  tft.fillScreen(ST77XX_BLACK); 
  bmpDraw("/picture4.bmp", 0, 0);
  delay(3000);
  pinOut();
  delay(3000);
}

void loop(void) {
  
  measureTemperature();
  delay(3000);
}

void printDirectory(File dir, int numTabs) {
  while (true) {
    File entry =  dir.openNextFile();
    if (! entry) {
      // no more files
      break;
    }
    for (uint8_t i = 0; i < numTabs; i++) {
      tft.print(' ');
      delay(50);
    }
    tft.print(entry.name());
    if (entry.isDirectory()) {
      tft.println("/");
      printDirectory(entry, numTabs + 1);
    } else {
      // files have sizes, directories do not
      tft.print("  ");
      tft.println(entry.size(), DEC);
    }
    entry.close();
  }
}

void pinOut(){
  tft.fillScreen(ST7735_BLACK);
  tft.setCursor(0, 0);
  tft.setTextColor(ST7735_GREEN);
  tft.setTextSize(2);
  tft.println("LOLIN");
  tft.println("D32 PRO");
  tft.setCursor(0, 35);
  tft.setTextSize(1);
  tft.println("TFT display test");

  tft.setTextColor(ST7735_RED);
  tft.setCursor(0, 55);
  tft.setTextSize(1);
  tft.println("PIN SETUP:");
  tft.setCursor(0, 65);
  tft.setTextSize(2);
  tft.println("TFT_CS  14");
  tft.println("TFT_RST 33");
  tft.println("TFT_DC  27");
  tft.println("SD_CS    4");
  delay(3000);
}

#define BUFFPIXEL 20
void bmpDraw(char *filename, uint8_t x, uint16_t y) {

  File     bmpFile;
  int      bmpWidth, bmpHeight;   // W+H in pixels
  uint8_t  bmpDepth;              // Bit depth (currently must be 24)
  uint32_t bmpImageoffset;        // Start of image data in file
  uint32_t rowSize;               // Not always = bmpWidth; may have padding
  uint8_t  sdbuffer[3*BUFFPIXEL]; // pixel buffer (R+G+B per pixel)
  uint8_t  buffidx = sizeof(sdbuffer); // Current position in sdbuffer
  boolean  goodBmp = false;       // Set to true on valid header parse
  boolean  flip    = true;        // BMP is stored bottom-to-top
  int      w, h, row, col;
  uint8_t  r, g, b;
  uint32_t pos = 0, startTime = millis();

  if((x >= tft.width()) || (y >= tft.height())) return;

  Serial.println();
  Serial.print(F("Loading image '"));
  Serial.print(filename);
  Serial.println('\'');

  // Open requested file on SD card
  if ((bmpFile = SD.open(filename)) == NULL) {
    Serial.print(F("File not found"));
    return;
  }

  // Parse BMP header
  if(read16(bmpFile) == 0x4D42) { // BMP signature
    Serial.print(F("File size: ")); Serial.println(read32(bmpFile));
    (void)read32(bmpFile); // Read & ignore creator bytes
    bmpImageoffset = read32(bmpFile); // Start of image data
    Serial.print(F("Image Offset: ")); Serial.println(bmpImageoffset, DEC);
    // Read DIB header
    Serial.print(F("Header size: ")); Serial.println(read32(bmpFile));
    bmpWidth  = read32(bmpFile);
    bmpHeight = read32(bmpFile);
    if(read16(bmpFile) == 1) { // # planes -- must be '1'
      bmpDepth = read16(bmpFile); // bits per pixel
      Serial.print(F("Bit Depth: ")); Serial.println(bmpDepth);
      if((bmpDepth == 24) && (read32(bmpFile) == 0)) { // 0 = uncompressed

        goodBmp = true; // Supported BMP format -- proceed!
        Serial.print(F("Image size: "));
        Serial.print(bmpWidth);
        Serial.print('x');
        Serial.println(bmpHeight);

        // BMP rows are padded (if needed) to 4-byte boundary
        rowSize = (bmpWidth * 3 + 3) & ~3;

        // If bmpHeight is negative, image is in top-down order.
        // This is not canon but has been observed in the wild.
        if(bmpHeight < 0) {
          bmpHeight = -bmpHeight;
          flip      = false;
        }

        // Crop area to be loaded
        w = bmpWidth;
        h = bmpHeight;
        if((x+w-1) >= tft.width())  w = tft.width()  - x;
        if((y+h-1) >= tft.height()) h = tft.height() - y;

        // Set TFT address window to clipped image bounds
        tft.setAddrWindow(x, y, x+w-1, y+h-1);

        for (row=0; row<h; row++) { // For each scanline...

          // Seek to start of scan line.  It might seem labor-
          // intensive to be doing this on every line, but this
          // method covers a lot of gritty details like cropping
          // and scanline padding.  Also, the seek only takes
          // place if the file position actually needs to change
          // (avoids a lot of cluster math in SD library).
          if(flip) // Bitmap is stored bottom-to-top order (normal BMP)
            pos = bmpImageoffset + (bmpHeight - 1 - row) * rowSize;
          else     // Bitmap is stored top-to-bottom
            pos = bmpImageoffset + row * rowSize;
          if(bmpFile.position() != pos) { // Need seek?
            bmpFile.seek(pos);
            buffidx = sizeof(sdbuffer); // Force buffer reload
          }

          for (col=0; col<w; col++) { // For each pixel...
            // Time to read more pixel data?
            if (buffidx >= sizeof(sdbuffer)) { // Indeed
              bmpFile.read(sdbuffer, sizeof(sdbuffer));
              buffidx = 0; // Set index to beginning
            }

            // Convert pixel from BMP to TFT format, push to display
            b = sdbuffer[buffidx++];
            g = sdbuffer[buffidx++];
            r = sdbuffer[buffidx++];
            tft.pushColor(tft.color565(r,g,b));
          } // end pixel
        } // end scanline
        Serial.print(F("Loaded in "));
        Serial.print(millis() - startTime);
        Serial.println(" ms");
      } // end goodBmp
    }
  }

  bmpFile.close();
  if(!goodBmp) Serial.println(F("BMP format not recognized."));
}


// These read 16- and 32-bit types from the SD card file.
// BMP data is stored little-endian, Arduino is little-endian too.
// May need to reverse subscript order if porting elsewhere.

uint16_t read16(File f) {
  uint16_t result;
  ((uint8_t *)&result)[0] = f.read(); // LSB
  ((uint8_t *)&result)[1] = f.read(); // MSB
  return result;
}

uint32_t read32(File f) {
  uint32_t result;
  ((uint8_t *)&result)[0] = f.read(); // LSB
  ((uint8_t *)&result)[1] = f.read();
  ((uint8_t *)&result)[2] = f.read();
  ((uint8_t *)&result)[3] = f.read(); // MSB
  return result;
}

void measureTemperature(){
  if(sht30.get()==0){
    
    tft.fillScreen(ST7735_BLACK);
    tft.setCursor(5, 10);
    
    tft.setTextColor(ST7735_WHITE);
    tft.setTextSize(1);
    tft.println("Temperature in C:");
    
    tft.setTextSize(2);
    tft.setCursor(5, 20);
    tft.print(sht30.cTemp);
    tft.drawCircle(70, 23, 3, ST77XX_WHITE);
    tft.println(" C");
    
    tft.setCursor(5, 40);
    tft.setTextSize(1);
    tft.println("Temperature in F:");

    tft.setTextSize(2);
    tft.setCursor(5, 50);
    tft.print(sht30.fTemp);
    tft.drawCircle(70, 53, 3, ST77XX_WHITE);
    tft.println(" F");
    
    tft.setCursor(5, 70);
    tft.setTextSize(1);
    tft.println("Relative Humidity:");

    tft.setCursor(5, 80);
    tft.setTextSize(2);
    tft.print(sht30.humidity);
    tft.println(" %");
  }
  else
  {
    tft.setTextColor(ST7735_RED);
    tft.fillScreen(ST7735_BLACK);
    tft.setCursor(0, 40);
    tft.println("ERROR:");
    tft.setTextSize(1);
    tft.setCursor(0, 60);
    tft.println("Unable to read data!");
  }
  delay(1000);
}

My LOLIN D32 PRO will not accept:

#include Adafruit_ST7735.h
and
#include <SD.h>

I've tried various libraries to Lolin 2.4 tft to work but I get this same message in Arduino:
"Error compiling for board LOLIN D32 PRO"

It will up load a programme without these two #includes, so the device seems to be working.

Hope you can help with what could be wrong.

.... it will load SD.h but not with Adafruit_GFX.h or Adafruit_ST7735.h.

The problem seems to be with the Adafruit Libraries.