Manage System Git Config with Puppet

example_usage.pp

class myweb::sites::wiki_example_com {

  wiki_base = '/var/www/sites/wiki.example.com'
  include ::profile::gitconfig

  profile::gitconfig::safe_directory {"${wiki_base}/code/mediawiki-1.35-LTS":}
  vcsrepo { "${wiki_base}/code/mediawiki-1.35-LTS/":
    ensure   => latest,
    provider => git,
    source   => '[email protected]:wiki/mediawiki-1.35-LTS.git',
    revision => 'master',
  }  
}

gitconfig.pp

# == Class: profile::gitconfig
#
# Control System-Wide Git Configuration
#
# === Authors
#
# Yehuda Katz <[email protected]>
#
class profile::gitconfig {

  $gitconfig_file = lookup('profile::gitconfig::file', {default_value => '/etc/gitconfig'})
  $gitconfig_dir  = lookup('profile::gitconfig::dir',  {default_value => '/etc/gitconfig.d'})

  Concat::Fragment <| tag == gitconfig |> -> Vcsrepo <| |>

  file { $gitconfig_file:
    ensure => present,
    owner  => 'root',
    group  => 'root',
    mode   => '0644',
  }

  file { $gitconfig_dir:
    ensure => directory,
    owner  => 'root',
    group  => 'root',
    mode   => '0755',
  }

  ini_setting { 'Include Puppet-Managed Git Config':
    ensure  => present,
    path    => $gitconfig_file,
    section => 'include',
    setting => 'path',
    value   => "${gitconfig_dir}/puppet",
  }

  concat { 'gitconfig':
    path  => "${gitconfig_dir}/puppet",
    owner => 'root',
    group => 'root',
    mode  => '0644',
    warn  => true,
  }

  # For ordering, space comes before /: The space is important
  concat::fragment { 'gitconfig-safedir- header':
    target  => 'gitconfig',
    content => "[safe]\n",
    order   => '10',
  }

}

safe_directory.pp

# == Class: profile::gitconfig::safe_directory
#
# Add `safe.directory` to system config
#
# === Authors
#
# Yehuda Katz <[email protected]>
#
define profile::gitconfig::safe_directory (
  Stdlib::Absolutepath $path = $title
) {

  if $path =~ /^.+\/$/ {
    fail("safe.directory can not have a trailing slash: ${path}")
  }

  concat::fragment { "gitconfig-safedir-${title}":
    target  => 'gitconfig',
    content => "        directory = ${path}\n",
    order   => '10',
    tag     => ['gitconfig'],
  }

}