psdoom-ng PKGBUILD

# Maintainer: Jonathan Lestrelin <[email protected]>

pkgname=psdoom-ng
pkgver=2017.10.02.2.3.0.20170825
pkgrel=1
pkgdesc="A FPS and operating system process killer (when you kill an enemy, it kills a process) based on psDooM and Chocolate Doom."
arch=('any')
url="https://github.com/keymon/psdoom-ng"
license=('GPL')
depends=('sdl' 'sdl_mixer' 'sdl_net' 'freedoom1')
source=("https://github.com/orsonteodoro/psdoom-ng1/archive/${pkgname}-${pkgver}.tar.gz" "https://gist.githubusercontent.com/yeoldegrove/0f7463a86aade97bdbe7346f8d1ea841/raw/8d7dfec1bbd6fe058f4d44b1e44124e7076d6875/psd_add_config.patch")
md5sums=('SKIP' 'SKIP')

build() {
    cd "psdoom-ng1-${pkgname}-${pkgver}"
    # don't run configure just now
    sed -i 's#^./configure.*##g' autogen.sh
    ./autogen.sh
    ./configure --prefix /usr
    # fix some buggy Makefiles
    sed -i 's#psdoom-ng.desktop#\#psdoom-ng.desktop#g' src/Makefile* Makefile*
    sed -i 's#CHANGELOG.psdoom-ng#ChangeLog.psdoom-ng#g' src/Makefile* Makefile*
    make
    # patch the wrapper script to create config files
    patch psd <../psd_add_config.patch
}

package() {
    cd "psdoom-ng1-${pkgname}-${pkgver}"
    # install custom levels
    mkdir -p ${pkgdir}/usr/share/games/doom
    tar xf contrib/psdoom-2000.05.03-data.tar.gz -C ${pkgdir}/usr/share/games/doom
    mv ${pkgdir}/usr/share/games/doom/psdoom-data/*.wad ${pkgdir}/usr/share/games/doom
    rm -rf ${pkgdir}/usr/share/games/doom/psdoom-data/
    # install everything else
    DESTDIR=${pkgdir} make install
}