lstree implementation by Haskell

LSTree.hs

module Main where
import Directory (getDirectoryContents)
import Data.Tree (drawTree, unfoldTreeM)
import System.Environment (getArgs)
import Control.Applicative ((<$>), (<*>), pure)
import System.Posix.Files (isSymbolicLink, isDirectory, 
                           readSymbolicLink,getSymbolicLinkStatus)
import System.FilePath.Posix ((</>), takeFileName)

main = getArgs >>= \args -> case args of
         [arg] -> putStrLn . drawTree =<< unfoldTreeM phi arg
         _     -> putStrLn "USAGE: lstree <dirpath>"
  where phi path =  proc =<< getSymbolicLinkStatus path
          where proc fstat 
                  | isSymbolicLink fstat = 
                     readSymbolicLink path >>= \lname -> 
                       pure ("@" ++ takeFileName path ++ " -> " ++ lname,[])
                  | isDirectory fstat = 
                     getDirectoryContents path >>= \children ->
                       (,) <$> pure (takeFileName path)
                           <*> pure [path </> child | child <- children, head child /= '.']
                  | otherwise = pure (takeFileName path,[])