atc_thermometer.nix

{ stdenvNoCC, fetchFromGitHub, telink-825x-sdk, tc32-gcc, python3 }:
stdenvNoCC.mkDerivation {
  pname = "ATC_Thermometer";
  version = "20201003";
  src = "${fetchFromGitHub {
    owner = "atc1441";
    repo = "ATC_MiThermometer";
    rev = "772348a2266ea22bd58795314be148a8154e6462";
    sha256 = "05ggw0c61fbhw751c5icpv31i0cjk2nx5nmnkixid07ajsmhb7fw";
  }}/ATC_Thermometer";
  enableParallelBuilding = true;
  nativeBuildInputs = [ tc32-gcc python3 ];
  makeFlags = [ "TEL_PATH=${telink-825x-sdk}" ];
  installPhase = ''
    runHook preInstall
    mkdir $out
    cp -r ATC_Thermometer.bin $_
    runHook postInstall
  '';
}

default.nix

with import ./pkgs.nix; atc_thermometer

pkgs.nix

import (builtins.fetchTarball channel:nixos-unstable) {
  overlays = [ (self: super: {
    tc32-gcc = super.callPackage ./tc32-gcc.nix {};
    telink-825x-sdk = super.callPackage ./telink-825x-sdk.nix {};
    atc_thermometer = super.callPackage ./atc_thermometer.nix {};
  }) ];
}

tc32-gcc.nix

{ stdenv
, fetchurl, autoPatchelfHook
, zlib, ncurses5, expat, libusb, libusb-compat-0_1
}:

stdenv.mkDerivation {
  pname = "tc32-gcc";
  version = "2.0";

  src = fetchurl {
    url = "http://shyboy.oss-cn-shenzhen.aliyuncs.com/readonly/tc32_gcc_v2.0.tar.bz2";
    sha256 = "0c5lj5wxwmjr1558cqnmskgr877ashndmkfsnjjdpcrx7sz59f1k";
  };

  buildInputs = [
    zlib ncurses5 expat
    libusb libusb-compat-0_1
  ];

  nativeBuildInputs = [
    autoPatchelfHook
  ];

  unpackPhase = ''
    tar xf $src
  '';

  installPhase = ''
    mkdir $out
    cp -r tc32/bin $out/bin
    cp -r tc32/lib $out/lib
    cp -r tc32/share $out/share
    # ...
    cp -r tc32/include $out/include
    cp -r tc32/tc32-elf $out/tc32-elf
  '';

  meta = {
    description = "Toolchain for the Telink TC32 platform, as prebuilt gcc binaries";
    platforms = [ "x86_64-linux" ];
  };
}

telink-825x-sdk.nix

{ stdenv, fetchFromGitHub }:
fetchFromGitHub {
  owner = "Ai-Thinker-Open";
  repo = "Telink_825X_SDK";
  rev = "3c93f1518b2da895ea2fef50eff0791cbedd5d9d";
  sha256 = "1www3wjx7ixqkjyvsjp1rpdpxxnbs70172rb3grsxdksw32b34vj";
}