mtranspose

gistfile1.scd

(
// ノコギリ波をつかう
SynthDef(\arp, { |gate=1, amp=0.1, sustain=1, freq=440, pan=0|
	var sig, env;
	env = EnvGen.kr(Env.adsr, gate, amp, 0, sustain, 2);
	sig = Mix(LFSaw.ar([freq,freq+0.1])).softclip;
	sig = RLPF.ar(sig, 4500, 0.5);
	sig = Pan2.ar(sig, pan, env);
	Out.ar(0, sig);
}).add;
)
(
~arpA = Pbind(\instrument, \arp, 
	\dur, Pseq([
		Pn(0.25, 4 * 14), 
		1, 1
	], 2),
	\legato, 0.5, 
	\amp, 0.45, 
	\scale, [2, 4, 5, 7, 9, 10, 12], 
	\degree, Pseq([
		Pseq([0, 0, 0, 0, 0, 7, 4, 0], 7), 
		-2, -3
	], inf),
	\octave, 3, 
	\mtranspose, Pseq([ // 注
		Pn(0,  4 * 8), 
		Pn(-2, 4 * 4), 
		Pn(-4, 4 * 2), 
		0, 0
	], inf),
	\pan, Pseq([
		Pser([-1, 1], 4 * 14), 
		0, 0
	], inf)
).play;
)
注
mtranspose は移旋 (modal transposition)
scale で決められた音階の開始音が移され、旋法変化する

ド、レ、ミ、ファ、ソ、ラ、シ、ド
Pbind(\degree, Pseries(0, 1, 8)).play;
レ、ミ、ファ、ソ、ラ、シ、ド、レ
Pbind(\degree, Pseries(0, 1, 8), \mtranspose, 1).play; // ドーリア旋法
ミ、ファ、ソ、ラ、シ、ド、レ、ミ
Pbind(\degree, Pseries(0, 1, 8), \mtranspose, 2).play; // フリジア旋法



実践１
mtranspose を使い、残りの４つ旋法を聴く


実践２
ctranspose (chromatic transposition) と比べる