harmony

gistfile1.scd

和音と配列

(
SynthDef(\hrm, { |amp, freq=440|
	var sig, env;
	env = EnvGen.kr(Env.perc, 1, amp, doneAction: 2);
	sig = Saw.ar([freq, freq*0.99]);
	sig = RLPF.ar(sig, 3200);
	Out.ar(0, sig * env);
}).add;
)
(
/* degree に配列を与えハーモニーをつくる
	実際には配列の要素の数だけ、hrm シンセが複数重ねられる */
~hrmA = Pbind(\instrument, \hrm, 
	\dur, Pseq([
		Pseq([1.5, 1.5, 1.5, 1.5, 1, 1, 2, 0.5, 1, 2.5, 1, 1], 1), 
		Pseq([1.5, 1.5, 1.5, 1.5, 1, 1, 2, 2, 2, 1, 1], 1)
	], 1),
	\legato, 1, 
	\scale, [2, 4, 5, 7, 9, 10, 12], 
	\degree, Pseq([
		Pseq([
			[2,0,-3], [3,0,-3], [4,0,-3], [2,0,-3], [1,-1,-3], [4,1,-1],
			[2,0,-3,-2], \, [1,-1,-4,-3], [0,-2,-5,-4], [0,-2,-5], [1,-0.9,-4]// 注
		], 1),
		Pseq([
			[2,0,-3], [3,0,-3], [4,0,-3], [2,0,-3], [1,-1,-3], [4,1,-1], 
			[2,0,-2], [4,2,0,-1], [7,5,4,2], [9,7,6,4], [8,6,4,3]
		], 1)
	], inf),
	\amp, 0.2
).play;
)
注
ある degree に +/- 0.1 すると半音上下する
-0.9 = -1 + 0.1 = 主音レの下のドより半音高いドのシャープ


実践１
デフォルトシンセで和音を鳴らし、和音進行をつくる

例
Pbind(\degree, [0, 2, 4]).play; // ドミソ


実践２
キーワード strum を使って和音のアルペジオ化

例
Pbind(\degree, [0, 2, 4, 6, 8, 10.1], \strum, 0.15).play; // ドミソシレファ#
strum や legato を変更してみよう