A timer implementation using "onended" event dispatched to AudioBufferSourceNode and OscillatorNode

waa_timer.coffee

window.AudioContext = window.AudioContext||window.webkitAudioContext

class Timer
  constructor: (@useOscillatorNode) ->
    @url = 'http://dl.dropbox.com/u/334064/silence100ms.wav'
    @cxt = new AudioContext
    @gainNode = @cxt.createGain()
    @gainNode.gain.value = 0.0
    @gainNode.connect(@cxt.destination)
    @oninit = () ->

  init: () ->
    if @useOscillatorNode
      @oninit()
    else
      request = new XMLHttpRequest
      request.open('GET', @url, true)
      request.responseType = 'arraybuffer'

      request.onload = () =>
        @cxt.decodeAudioData request.response, (buf) =>
          @buffer = buf
          @oninit()
      request.send(null)

  setTimeout: (fn, time) ->
    time /= 1000.0
    currentTime = @cxt.currentTime
    
    if @useOscillatorNode
      source = @cxt.createOscillator()
    else
      source = @cxt.createBufferSource()
      source.buffer = @buffer
      source.loop = true

    source.onended = fn
    source.connect(@gainNode);
    source.start(currentTime)
    source.stop(currentTime + time)