Example of a Terraform module that creates an API Gateway to send requests to an arbitrary API

README.md

Inspired by https://qiita.com/masaminh/items/17edb2aaeb78c4c7274e

main.tf

resource "random_string" "api-id" {
  length  = "16"
  special = false
}

resource "aws_api_gateway_rest_api" "main" {
  name        = "http-caller-${random_string.api-id.result}"
  description = "Call ${var.method} ${var.uri}"

  body = jsonencode({
    openapi = "3.0.1"
    info = {
      title   = "example"
      version = "1.0"
    }
    paths = {
      "/" = {
        lower(var.method) = {
          x-amazon-apigateway-integration = {
            httpMethod           = var.method
            payloadFormatVersion = "1.0"
            type                 = "HTTP_PROXY"
            uri                  = var.uri
          }
        }
      }
    }
  })

  endpoint_configuration {
    types = ["REGIONAL"]
  }
}

resource "aws_api_gateway_deployment" "main" {
  rest_api_id = aws_api_gateway_rest_api.main.id

  triggers = {
    redeployment = sha1(jsonencode(aws_api_gateway_rest_api.main.body))
  }

  lifecycle {
    create_before_destroy = true
  }
}

resource "aws_api_gateway_stage" "prod" {
  deployment_id = aws_api_gateway_deployment.main.id
  rest_api_id   = aws_api_gateway_rest_api.main.id
  stage_name    = "prod"
}

outputs.tf

output "api_endpoint" {
  value = trimsuffix(trimprefix(aws_api_gateway_deployment.main.invoke_url, "https://"), "/")
}

output "method" {
  value = var.method
}

output "stage" {
  value = aws_api_gateway_stage.prod.stage_name
}

output "path" {
  value = "/"
}

variables.tf

variable "method" {
  type    = string
  default = "GET"
}

variable "uri" {
  type = string
}