Nix code to build a patched version of `libgccjit.so` for <https://github.com/rust-lang/rustc_codegen_gcc>

gccjit.nix

with import <nixpkgs> {};
with lib;

let
  antoyoGccRev = "72cb89f82a6c9c5471f0b2c122b21dbe387c7904";
  gccjit = (gcc11.cc.overrideAttrs (oldAttrs: oldAttrs // {
    src = fetchFromGitHub {
      owner = "antoyo";
      repo = "gcc";
      rev = antoyoGccRev;
      sha256 = "+h/ezfeEs+VoPjK1nl3LKk+proeGaoNQEduwZ+2aJos=";
    };
    name = "libgccjit";
    version = antoyoGccRev;
    nativeBuildInputs = oldAttrs.nativeBuildInputs
      ++ [ flex ];
    prePatch = ''
      mv gcc/gcc.cc gcc/gcc.c
      mv gcc/cppdefault.cc gcc/cppdefault.c
    '';
    postPatch = oldAttrs.postPatch + ''
      mv gcc/gcc.c gcc/gcc.cc
      mv gcc/cppdefault.c gcc/cppdefault.cc
    '';
    configureFlags = oldAttrs.configureFlags ++
      [ "--disable-werror" ];
  })).override {
    langFortran = false;
    langCC = false;
    langC = false;
    profiledCompiler = false;
    langJit = true;
    enableLTO = false;
    # noSysDirs = false;
  };
in
runCommand "dummy" rec {
  buildInputs = [
    gccjit
  ];
  GCC_PATH = "${gccjit}/lib";
} ""