tvheadend-git PKGBUILD

PKGBUILD

# Maintainer: Benjamin Hedrich <kiwisauce (a) pagenotfound (dot) de>
# Contributor: Dan Ziemba <[email protected]>
# Based on package hts-tvheadend-svn by azleifel <azleifel at googlemail dot com>

pkgname=tvheadend-git
_gitname='tvheadend'
pkgver=6026+g54533b3
pkgrel=1
pkgdesc="TV streaming server for Linux"
arch=('i686' 'x86_64')
url="https://tvheadend.org/"
license=('GPL3')
depends=('avahi' 'openssl' 'python2' 'uriparser' 'ffmpeg')
makedepends=('git')
optdepends=('xmltv: For an alternative source of programme listings')
provides=('tvheadend')
conflicts=('tvheadend' 'hts-tvheadend' 'hts-tvheadend-svn')
install=tvheadend.install

source=("git+https://github.com/tvheadend/tvheadend.git"
	'tvheadend.service')

md5sums=('SKIP'
         'b546f4486f0d28bea13ad1fb676acb27')

pkgver() {
	cd "${srcdir}/${_gitname}"
	echo $(git rev-list --count HEAD)+g$(git rev-parse --short HEAD)
}

build() {
	cd "${srcdir}/${_gitname}"
	./configure --prefix=/usr --mandir=/usr/share/man/man1 --python=python2 --release
	make
}

package() {
	cd "${srcdir}/${_gitname}"
	make DESTDIR="$pkgdir/" install
	install -D -m 644 "$srcdir/tvheadend.service" "$pkgdir/usr/lib/systemd/system/tvheadend.service"
}