Basic module

module.coffee

define ->
  moduleKeywords = ['extended', 'included']

  ###
  Ruby-like mixin functionality for CoffeeScript
  @see http://arcturo.github.io/library/coffeescript/03_classes.html
  ###
  class Module
    ###
    Copies the properties of the mixin onto the object
    @param obj [Object] A mixin
    ```
    # To extend a Class
    @extend SomeClass::
    # To extend an Object
    @extend SomeObject
    # Keep in mind that :: in coffee stands for prototype
    ```
    ###
    @extend: (obj) ->
      for key, value of obj when key not in moduleKeywords
        @[key] = value

      obj.extended?.apply(@)
      @

    ###
    Copies the mixins properties onto the prototype
    The mixin is either a Class or an Object
    @note To include classes do the following
    ```
    # To include a Class
    @include SomeClass::
    # To include an Object
    @include SomeObject
    ```
    @param obj [Object] A mixin
    ###
    @include: (obj) ->
      for key, value of obj when key not in moduleKeywords
        # Assign properties to the prototype
        @::[key] = value

      obj.included?.apply(@)
      @