form-triggered-send-email.html

<form class="smartcapture-content-wrapper fuelux" role="form" action="%%=RequestParameter('PAGEURL')=%%" method="GET">
   <span>
       <label for="email">Email:</label>
       <input type="email" class="form-control" id="email" name="email" value="%%=v(@email)=%%" required="">
   </span> 
   <button class="sc-button" type="submit" name="Submit" id="Submit" value="Success">Submit</button>
</form>

%%[
SET @email = RequestParameter("email")
IF @email != "" THEN

VAR @ts, @tsDef, @ts_extkey, @ts_email, @ts_sub, @ts_attr, @tsctr, @ts_subkey, @ts_statusCode, @ts_statusMsg, @errorCode
 
SET @ts = CreateObject("TriggeredSend")
SET @tsDef = CreateObject("TriggeredSendDefinition")
SET @ts_extkey = "{{TriggeredSendExternalKey}}"
SET @ts_email = QueryParameter("email")

SetObjectProperty(@tsDef, "CustomerKey", @ts_extkey)
SetObjectProperty(@ts, "TriggeredSendDefinition", @tsDef)
 
SET @ts_sub = CreateObject("Subscriber")
SetObjectProperty(@ts_sub, "EmailAddress", @ts_email)
SetObjectProperty(@ts_sub, "SubscriberKey", @ts_email)

AddObjectArrayItem(@ts, "Subscribers", @ts_sub)

SET @ts_statusCode = InvokeCreate(@ts, @ts_statusMsg, @errorCode)

IF @ts_statusCode != "OK" THEN
 RaiseError(@ts_statusMsg, 0, @ts_statusCode, @errorCode)
ENDIF

]%%

<br><b>Recipient email:</b> %%=v(@email)=%%
<br><b>Triggered Send status code:</b> %%=v(@ts_statusCode)=%%
<br><b>Triggered Send status message:</b> %%=v(@ts_statusMsg)=%%
<br><b>Triggered Send error code:</b> %%=v(@errorCode)=%%

%%[
ENDIF
]%%