WORD Макросы для сохранения слияния и рассылки в отдельные файлы формата DOC или PDF

SaveAs_merged_doc.vb

Sub ToTranslitDoc()
    Dim i As Long
    Dim oMerge As MailMerge
    Dim oData As MailMergeDataSource
    
    Set oMerge = ActiveDocument.MailMerge
    Set oData = oMerge.DataSource
    
    Application.ScreenUpdating = False
    For i = 1 To oData.RecordCount
        With oData
            .FirstRecord = i
            .LastRecord = i
            .ActiveRecord = i
        End With
        With oMerge
            .Destination = wdSendToNewDocument
            .Execute Pause:=False
        End With
        With ActiveDocument
            .SaveAs ("d:\TMP\" & oData.DataFields("Translit").Value & ".doc")
            .Close
        End With
    Next i
    Set oData = Nothing
    Set oMerge = Nothing
    Application.ScreenUpdating = True
End Sub
Sub ToTranslitPdf()
    Dim i As Long
    Dim oMerge As MailMerge
    Dim oData As MailMergeDataSource
    
    Set oMerge = ActiveDocument.MailMerge
    Set oData = oMerge.DataSource
    
    Application.ScreenUpdating = False
    For i = 1 To oData.RecordCount
        With oData
            .FirstRecord = i
            .LastRecord = i
            .ActiveRecord = i
        End With
        With oMerge
            .Destination = wdSendToNewDocument
            .Execute Pause:=False
        End With
        With ActiveDocument
            .SaveAs FileName:="d:\TMP\" & oData.DataFields("Translit").Value & ".pdf", FileFormat:=wdFormatPDF
            .Close (False)
        End With
    Next i
    Set oData = Nothing
    Set oMerge = Nothing
    Application.ScreenUpdating = True
End Sub

добрый день, а можно ли в этот макрос дописать код что еще и сохранение было с именем файла взятое из определенной ячейки ? был бы рад если бы вы мне помогли!

В строке .SaveAs FileName:="d:\TMP\" & oData.DataFields("Translit").Value & ".pdf" именно это и происходит, берется значения из поля с названием Translit.

Подскажите, пожалуйста, как можно воспользоваться данным макросом, как его правильно настроить и применять? Извините, первый раз сталкиваюсь с макросами, нужен ликбез.