SetupAuditTrails.cls

class SetupAuditTrails {
    public Map<String, Set<String>> getModifiedClassesSince(Id sinceTrailId) {
        return getModifiedClassesSince(sinceDate(sinceTrailId));
    }

    public Map<String, Set<String>> getModifiedClassesSince(DateTime sinceDate) {
        Map<String, Set<String>> changes = new Map<String, Set<String>>();
        
        for (SetupAuditTrail t : [
            SELECT display
            FROM SetupAuditTrail
            WHERE createdDate >= :sinceDate
                AND action IN ('changedApexClass', 'createdApexClass', 'deletedApexClass')
            ORDER BY action, display
        ]) {
            String[] parts = t.display.split(' ');
            String action = parts[0];
            String className = parts[1];
            
            if (!changes.containsKey(action)) {
                changes.put(action, new Set<String>());
            }

            changes.get(action).add(className);
        }
        
        return changes;
    }
    
    public Map<String, Set<String>> getChangesSince(Id sinceTrailId) {
        return getChangesSince(sinceDate(sinceTrailId));
    }
    
    public Map<String, Set<String>> getChangesSince(DateTime sinceDate) {
        Map<String, Set<String>> changes = new Map<String, Set<String>>();
        
        for (SetupAuditTrail t : [
            SELECT display, section
            FROM SetupAuditTrail
            WHERE createdDate >= :sinceDate
            ORDER BY createdDate
        ]) {
            if (!changes.containsKey(t.section)) {
                changes.put(t.section, new Set<String>());
            }

            changes.get(t.section).add(t.display);
        }
        
        return changes;
    }
    
    DateTime sinceDate(Id sinceTrailId) {
        try {
            return [SELECT createdDate FROM SetupAuditTrail WHERE id = :sinceTrailId].createdDate;
        } catch (Exception e) {
            return DateTime.now().addYears(-5);
        }
    }
}