gcviewer-1.32

PKGBUILD

# Maintainer: Julien Nicoulaud <[email protected]>
# Source: https://github.com/nicoulaj/archlinux-packages
pkgname=gcviewer
pkgver=1.32
pkgrel=1
pkgdesc="Java garbage collector logs analyzer/visualizer."
arch=(any)
url="https://github.com/chewiebug/GCViewer"
license=(LGPL)
depends=('java-runtime>=6')
changelog=Changelog
source=("http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.jar")
md5sums=('d2b7e314461ecdcfd171f701cbec3d86')
noextract=("${pkgname}-${pkgver}.jar")

prepare() {
  jar xf  ${pkgname}-${pkgver}.jar META-INF/README META-INF/LICENSE.txt
}

build() {
  msg2 "Generate executable script..."
  cat > "${srcdir}/${pkgname}.sh" << EOF
#!/bin/sh
"\$JAVA_HOME/bin/java" -jar '/usr/share/java/${pkgname}/${pkgname}.jar' "\$@"
EOF
}

package() {
  msg2 "Install the library at /usr/share/java/${pkgname}..."
  install -Dm644 "${srcdir}/${pkgname}-${pkgver}.jar" "${pkgdir}/usr/share/java/${pkgname}/${pkgname}.jar"

  msg2 "Install documentation resources at /usr/share/doc/${pkgname}..."
  install -Dm644 "${srcdir}/META-INF/README" "${pkgdir}/usr/share/doc/${pkgname}/README"

  msg2 "Install license resources at /usr/share/licenses/${pkgname}..."
  install -Dm644 "${srcdir}/META-INF/LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"

  msg2 "Install an executable at /usr/bin/${pkgname}..."
  install -Dm755 "${srcdir}/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"
}

# vim:set ts=2 sw=2 et: