Vimlink - using the clientserver feature

_vimlink

#compdef vimlink

_vimlink() {
    local -a vimse
    vimse=($(/usr/bin/vim --serverlist))

    if (( CURRENT == 2 )); then
        _arguments '*:vimserver:($vimse)'
    fi

    return 0
}

_vimlink

prompt

function vimlinked()
{
    if [[ -z ${VIMLINKED} ]]
    then
        echo ""
    else
        echo "${PR_MAGENTA} ⚓ ${VIMLINKED}"
    fi
}

local vilnk='$(vimlinked)'
local inner="${vilnk} ${cwd}${colon}${user_host}"

RPROMPT="${PR_RESET}${bracket_open}${inner}${bracket_close}${PR_RESET}"

vimlink

if [[ $# -ge 1 ]]
then
    if [[ $# -gt 1 ]]
    then
        print "only one argument allowed" > /dev/fd/2
        return 23
    else
        servername=$(echo ${1} | tr "[:lower:]" "[:upper:]")
    fi
else
    print "please specify a servername" > /dev/fd/2
    return 13
fi

_redefines()
{
    # force vim to cd with you
    cd()
    {
        builtin cd $*
        /usr/bin/vim --servername ${VIMLINKED} --remote-send ":cd ${PWD}<CR>"
    }

    # open files in linked vim
    vim()
    {
        if [[ ${1} =~ "^-.*" ]]
        then
            /usr/bin/vim $*
        else
            /usr/bin/vim --servername ${VIMLINKED} --remote $*
        fi
    }
}

print "trying to link to ${servername}"
vim --serverlist | grep ${servername} > /dev/null

if [[ $? -eq 0 ]]
then
    if [[ $VIMLINKED != ${servername} ]]
    then
        print "now linked to ${servername}"
        export VIMLINKED=${servername}
        _redefines
        cd .
    else
        print "this shell is already linked to ${VIMLINKED}"
    fi
else
    print "there is no server ${servername}"
fi

return 0

# vim: ft=zsh

vimunlink

cd() { builtin cd $*}
vim() { /usr/bin/vim $* }
unset VIMLINKED

# vim: ft=zsh