code for compmus class @ avarts 5 nov 2013

compmus131105

(
a = { | gate = 1 |
	var env, envPlayer, source;
	
	env = Env.adsr;
	envPlayer = EnvGen.kr(env, gate);
	
	source = WhiteNoise.ar(0.1);
	
	Out.ar(0, source * envPlayer);
}.play;
)

a.set(\gate, 0);


(
a = { | dur = 1 |
	var env, envPlayer, source;
	
	env = Env.perc;
	envPlayer = EnvGen.kr(env, timeScale: dur / 1.01);
	
	source = WhiteNoise.ar(0.1);
	
	Out.ar(0, source * envPlayer);
}.play;
)

(
SynthDef("perc", { | dur = 1 |
	var env, envPlayer, source;
	
	env = Env.perc;
	envPlayer = EnvGen.kr(
		env, 
		timeScale: dur / 1.01,
		doneAction: 2
	);
	
	source = WhiteNoise.ar(0.1);
	
	Out.ar(0, source * envPlayer);
}).add;
)

a = Synth("perc");

(
r = {
	var rhythm;
	~r = 4;
	rhythm = Pseq([0.1, 0.1, 0.2, 0.4], inf).asStream;
	loop {
		(rhythm.next * ~r).wait;
		Synth(\perc, [\dur, 0.1 rrand: 2]);
	}
}.fork
)

~r = 0.5;
~r = 0.1;
~r = 2;



(
SynthDef("ping", { | freq = 400, amp = 0.1, dur = 1 |
	var env, envPlayer, source;
	
	env = Env.perc;
	envPlayer = EnvGen.kr(
		env, 
		timeScale: dur / 1.01,
		doneAction: 2
	);
	
	source = SinOsc.ar(freq, 0, amp);
	
	Out.ar(0, source * envPlayer);
}).add;
)

Synth("ping");

(
r = {
	var melody;
	melody = Pseq(([0, 3, 7, 5, 8, 7, 11] + 60).midicps, inf);
	melody = melody.asStream;
	~dur = 0.1;
	
	loop {
		Synth("ping", [\freq, melody.next, \amp, 0.5]);
		~dur.wait;
	}
}.fork
)

~dur = 0.15;