Supporting Rails Nested Resources in Batman.js

model.js.coffee

class App.Model extends Batman.Model

  @persist App.Storage

  @encodeAttributesFor: ->
    @encodeAttributesForKeys ?= []
    for key in arguments
      if typeof key == 'string'
        @encodeAttributesForKeys.splice(index,1) if (index = @encodeAttributesForKeys.indexOf(key)) > 0
        @encodeAttributesForKeys.push key

storage.js.coffee

class App.Storage extends Batman.RailsStorage

  @::before 'create', 'update', (env, next) ->
    if env.subject.constructor.encodeAttributesForKeys?
      data = env.options.data
      if namespace = @recordJsonNamespace(env.subject)
        obj = data[namespace]
      else
        obj = data
      for key in env.subject.constructor.encodeAttributesForKeys
        if obj[key]
          obj["#{key}_attributes"] = obj[key] if obj[key].length
          delete obj[key]
    next()

  @::after 'update', @skipIfError (env, next) ->
    if env.subject and env.subject.constructor.encodeAttributesForKeys?
      for key in env.subject.constructor.encodeAttributesForKeys
        objects = env.subject.get(key)
        if objects?.constructor.name == 'AssociationSet'
          objects.forEach (object) ->
            if object.get('_destroy')
              objects.remove(object) 
            else
              object.get('dirtyKeys').clear()
              object.get('_dirtiedKeys').clear()

store.js.coffee

class App.Store extends App.Model
  
  @hasMany 'products'
  @encodeAttributesFor 'products'

Any chance of this getting merged into BatmanJS core?