Run a Python script in a conda environment from a batch file

run_python_script_in_conda_env.bat

@echo OFF
rem How to run a Python script in a given conda environment from a batch file.

rem It doesn't require:
rem - conda to be in the PATH
rem - cmd.exe to be initialized with conda init

rem Define here the path to your conda installation
set CONDAPATH=C:\ProgramData\Miniconda3
rem Define here the name of the environment
set ENVNAME=someenv

rem The following command activates the base environment.
rem call C:\ProgramData\Miniconda3\Scripts\activate.bat C:\ProgramData\Miniconda3
if %ENVNAME%==base (set ENVPATH=%CONDAPATH%) else (set ENVPATH=%CONDAPATH%\envs\%ENVNAME%)

rem Activate the conda environment
rem Using call is required here, see: https://stackoverflow.com/questions/24678144/conda-environments-and-bat-files
call %CONDAPATH%\Scripts\activate.bat %ENVPATH%

rem Run a python script in that environment
python script.py

rem Deactivate the environment
call conda deactivate

rem If conda is directly available from the command line then the following code works.
rem call activate someenv
rem python script.py
rem conda deactivate

rem One could also use the conda run command
rem conda run -n someenv python script.py

Works flawless. Thanks for sharing! 👌

Works as expected, Thanks

Thank you it worked!

It worked for me too. Thank you!

Thanks

Thanks for sharing!

Thank you!

Thanks! Somehow, from time to time I encounter the following issue:

CondaHTTPError: HTTP 000 CONNECTION FAILED for url https://conda.anaconda.org/conda-forge/win-64/repodata.json
Elapsed: -
An HTTP error occurred when trying to retrieve this URL.
HTTP errors are often intermittent, and a simple retry will get you on your way.
'https://conda.anaconda.org/conda-forge/win-64'
The creation process encountered an error, please check the output

Does anybody have an idea why?

@maximlt Love it!

works like a charm, is literally self explanatory and saves my day.
Thank you!

Over some time I created this version which checks more directories and it goes both for Anaconda and Miniconda paths. Maybe it is helpfull for somebody else, too.

Thank you for sharing, you save my day!

Thank you very much for the way to run a python script with the environment in 1 command. Didn't know about that and it saved me.
conda run -n someenv python script.py

Thanks

Thanks, that's helped

Works like a charm.

works perfectly.

Thank you for sharing!

This works perfectly! thanks

Legendary

Thank you!

Thank you, it works perfectly.

Saved me so much trouble shooting! Thank you!

Thanks for sharing!!! this save me lot of issues.

Thanks. The "call" part is what I was missing. Appreciate it!

Thanks for this, for some strange reason I had to change this line:
call %CONDAPATH%\Scripts\activate.bat %ENVPATH%

to:
call %CONDAPATH%\Scripts\activate.bat %ENVNAME%

Thanks!