gistfile1.pde

// by davebees

int[][] result;
float t;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 96;        
float shutterAngle = .5;

boolean recording = false;

void setup_() {
  size(500, 500, P3D);
  smooth(8);
  rectMode(CENTER);
  fill(255);
  noStroke();
  for (int i=0; i<N; i++)
    b[i] = new boxx();
}

class boxx {
  float x, y, w, h, ph;

  boxx() {
    x = random(-width*2, width*2);
    y = random(-height*2, height*2);
    w = random(height*.1,height*.25);
    h = random(height*.35);
    ph = random(.5);
  }

  void draw(float q) {
    beginShape(QUADS);
    vertex(x-w/2, y-w/2, 0);
    vertex(x+w/2, y-w/2, 0);
    vertex(x+w/2, y-w/2, q*h);
    vertex(x-w/2, y-w/2, q*h);

    vertex(x-w/2, y+w/2, 0);
    vertex(x+w/2, y+w/2, 0);
    vertex(x+w/2, y+w/2, q*h);
    vertex(x-w/2, y+w/2, q*h);

    vertex(x-w/2, y-w/2, 0);
    vertex(x-w/2, y+w/2, 0);
    vertex(x-w/2, y+w/2, q*h);
    vertex(x-w/2, y-w/2, q*h);

    vertex(x+w/2, y-w/2, 0);
    vertex(x+w/2, y+w/2, 0);
    vertex(x+w/2, y+w/2, q*h);
    vertex(x+w/2, y-w/2, q*h);

    vertex(x-w/2, y-w/2, q*h);
    vertex(x+w/2, y-w/2, q*h);
    vertex(x+w/2, y+w/2, q*h);
    vertex(x-w/2, y+w/2, q*h);
    endShape();
  }
}

float x, y, tt;
float br;
int N = 3600;

boxx[] b = new boxx[N];

void draw_() {
  br = 255;
  directionalLight(br, br, br, -2, 1, -2);
  directionalLight(br*.5, br*.5, br*.5, 1, 1, -2);
  background(255); 
  pushMatrix();
  translate(width/2, height/2, -100);
  rotateX(PI*.25);
  rotate(PI*.33);
  for (int i=0; i<N; i++)
    b[i].draw(map(cos(TWO_PI*t - 0.000025*(sq(b[i].x)+sq(b[i].y))+b[i].ph), 1, -1, 0, 1));
  popMatrix();
  noLights();
}