gistfile1.pde

// by dw @ bees & bombs

int[][] result;
float t;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 120;        
float shutterAngle = .8;

boolean recording = false;

void setup_() {
  size(500, 500, P3D);
  smooth(8);
  noFill();
  colorMode(HSB);
}

float r = 85;
float aa;
float x, y, tt;
float th1, th2;
float sp = 2;
int N = 120, n = 18;
float th;

void draw_() {
  background(29, 40, 30);
  pushMatrix();
  translate(width/2, height/2-20, 60);
  rotateX(-.5);
  for (int a=0; a<n; a++) {
    aa = a+2*t;
    pushMatrix();
    rotateY(aa*TWO_PI/n);
    translate(0, 0, -1.15*r);
    rotateY(-HALF_PI*.75);
    tt = t + aa/float(n);
    th1 = TWO_PI*tt;
    th2 = TWO_PI*tt + PI;
    beginShape();
    for (int i=0; i<N; i++) {
      stroke((aa/float(n)*256+.5) % 255, 240, 255);
      th = lerp(th1, th2, i/float(N));
      strokeWeight(map(pow(i, 2), 0, pow(N, 2), 0, 10));
      vertex(r*cos(th), -r*sin(th), 0);
    }
    endShape();
    popMatrix();
  }

  popMatrix();
}