relational_mapper.coffee

      window.mapRelations = (model,doThis,exclusions=[]) ->
        result = doThis.call(model,model)
        exclusions.push(model)
        if model instanceof Backbone.RelationalModel && !model.isLocked()
          model.acquire()
          _(model.getRelations()).each (relation) =>
            related = relation.related
            unless _(exclusions).include(related)
              if related instanceof Backbone.Collection
                result[relation.key] = []
                related.each (item) ->
                  result[relation.key].push(mapRelations(item,doThis,exclusions))
              else
                result[relation.key] = mapRelations(related,doThis,exclusions)
          model.release()
        result

relational_mapper_spec.coffee

      describe "mapping relations", ->
        context "get all the IDs", ->
          Given -> @toy = new Toy
          Given -> @cane = new BambooCane
          Given -> @model.set toy: @toy
          Given -> @model.get('bambooCanes').reset(@cane)
          When -> @result = window.mapRelations(@model, (m) -> id: m.cid)
          Then -> expect(@result).toEqual
            id: @model.cid
            toy:
              id: @toy.cid
            bambooCanes: [
              id: @cane.cid
            ]