Trying to test selection event

DataSetControlView.coffee

class ContactUs.Views.DataSetControlView extends ContactUs.Views.SerializableView

  template: "performance/data-set-control"

  id: 'dataset-select'

  events:
    'change': "optionSelected"

  initialize: -> 
      @collection.bind "reset", => @render()

  serialize: -> 
      options: @collection.toJSON()
      
  optionSelected: (event) ->
    value = $("option:selected", $(event.currentTarget)).val();
    ContactUs.Notification.trigger ContactUs.Notification.datasetChanged, value

DataSetControlView_spec.coffee

describe "ContactUs.Views.DataSetControlView", ->
  Given -> @collection = new Backbone.Collection
  Given -> @subject = new ContactUs.Views.DataSetControlView
    collection: @collection
  
  Then -> @subject.template == "performance/data-set-control"
  Then -> @subject.id == "dataset-select"
  
  describe "model binding", ->
    Given -> spyOn(@subject, 'render')
    When -> @collection.reset()
    Then -> expect(@subject.render).toHaveBeenCalled()
    
  describe "#serialize", ->
    Given -> @collection.add { a : "FOO!"}
    When -> @result = @subject.serialize()
    Then -> expect(@result).toEqual
      options : [ a : 'FOO!']
      
  describe "#optionSelected", ->
    VALUE = 'blerg'
    Given -> spyOn(ContactUs.Notification, 'trigger')
    Given -> @$select = @subject.$el.affix("select#dataset-select option[value=#{VALUE}]+option[value=foo]")
    Given -> @e = currentTarget: @$select[0]
    When -> @subject.optionSelected(@e)
    Then -> expect(ContactUs.Notification.trigger).toHaveBeenCalledWith(ContactUs.Notification.datasetChanged, VALUE)

prereq_stuff.coffee

window.ContactUs = { 
  Views: {}
  Notification: {
    trigger: ->
    datasetChanged: "What is this? A Value?"
  }
}

class ContactUs.Views.SerializableView extends Backbone.View

Works on tryjasmine here:

http://tryjasmine.com/?gist=1885097